//var YFPslice = 1; 
//var FRETslice = 2;
//var CFPslice = 3;
var tab = " \t ";
// based on controls, FRET bg should be 180, but all experiments approx 60 greater
var bg = newArray(200, 240, 124);  // based on "n=1/3. YFP CFP untethered"
var CFPspillover = 0.94;  // CFP * CFPspillover is subtracted from FRET signal before ratio
var YFPspillover = 0.15;  // YFP * YFPspillover is subtracted from FRET signal before ratio


macro "measure all cells [F4]" {  // original version
  run("Set Measurements...", "mean redirect=None decimal=4");
  print(getTitle());
  print("cell# \t YFP \t FRET \t CFP \t ratio");
  means = newArray(3);
  for (i=0;  i<roiManager("count");  i++){
    roiManager("select", i);
    outputstring = "" + d2s((i+1),0) + tab;
    for (s=1; s<=3; s++) {
      setSlice(s);
      run("Measure");
      means[s-1] = getResult("Mean", nResults-1) - bg[s-1];
      outputstring = outputstring + d2s(means[s-1],0) + tab;
    }
    means[1] = means[1] - (means[0] * YFPspillover);
    //means[1] = means[1] - (means[2] * CFPspillover);
    outputstring = outputstring + d2s((means[1]/means[2]),3) + tab;
    print(outputstring);
  }  // for  i

}


//================================================//
macro "Measure all files in directory [F5]" {
  openPath = getDirectory("Choose a Directory");
  fileList = getFileList(openPath);
  print(openPath);
  means = newArray(3);              
  roiManager("Reset");
  print("Cell# \t YFP \t FRET \t CFP \t rawRatio \t bgSubRatio \t CFPadjRatio");    //\t postYFPadj

  for (i=0; i<fileList.length; i++){
    outputstring = ""; 
    run("Close All");   
    roiManager("Reset");
    tempname = replace(fileList[i], ".dv", "") + "RoiSet.zip";
    if ((endsWith(fileList[i], ".dv")) && (File.exists(openPath+tempname)))   {          
      print(fileList[i] + "        " + tempname);
      open(openPath + fileList[i]);
      open(openPath + tempname);

      for (roi=0;  roi<roiManager("count");  roi++){
        roiManager("select", roi);
        outputstring = "" + d2s((roi+1),0) + tab;
        for (s=1; s<=3; s++) {
          setSlice(s);
          run("Measure");
          means[s-1] = getResult("Mean", nResults-1);
          outputstring = outputstring + d2s(means[s-1],0) + tab;
        }  // for each slice
        outputstring = outputstring + d2s((means[1]/means[2]),2) + tab;    // raw ratio no bg subtraction
        for (ch=0; ch<3; ch++)
          means[ch] = means[ch] - bg[ch];    // subtract bg from each channel
        outputstring = outputstring + d2s((means[1]/means[2]),2) + tab;    // bg subbed ratio         
        means[1] = means[1] * CFPspillover;   // do the CFP spillover adjustment
        outputstring = outputstring + d2s((means[1]/means[2]),2) + tab;    // ratio after CFP adjustment  
        //means[1] = means[1] - (means[0] * YFPspillover);
        //outputstring = outputstring + d2s((means[1]/means[2]),2) + tab;    // ratio after YFP adjustment
        print(outputstring);
      }  // for each roi
    }  // if
  } // for i
  selectWindow("Log");
  print("");
}  // "Measure all files in directory [F5]" 



//===================================================
macro "Over-Under LUT [F6]" {
    reds = newArray(256); 
    greens = newArray(256); 
    blues = newArray(256);
    for (i=0; i<256; i++) {
        reds[i] = i;
        greens[i] = i;
        blues[i] = i;
    }
    greens[255] = 0;    // over is red
    blues[255] = 0;
    reds[0] = 0;              // under is blue
    greens[0] = 0;
    setLut(reds, greens, blues);
}